Empêcher le relancement d'explorer.exe

Bonjour tout le monde,

Je vous explique mon problème :

J'ai créer un fichier batch contenant diverses commandes visant pour la plupart à kill des processus inutiles.

En effet, quand je joue, je n'estime pas avoir besoin d'explorer entre autres... c'est pourquoi j'ai crée ce fichier de passage en "mode jeu".

Mon souci est que quand je kill le processus explorer.exe (avec tskill), il se relance automatiquement (chose parfois sympa mais là non !). :(

Après avoir passé pas mal de temps à chercher sur divers forums, j'ai pu lire qu'il y a une clé dans le registre de windaube oups pardon, de windows qui configure justement ce lancement auto d'explorer.exe

Mais pas moyen de trouver cette clé... :@ :@ :@

quelqu'un pourrait-il m'aider svp ??? :neutre:
Edité le 29/02/2008 à 00:32

salut,
C'est p'être à ca que tu penses soit fixer l'utilisation de la ram.
www.laboratoire-microsoft.org...
Parce que envisager de le supprimer totalement est une mauvaise idée. Car c'est lui qui gère le shell (interface utilisateur), le bureau, la barre des tâches...et 'accessoirement' le navigateur des fichiers.

C'est sympa, mais non moi ce que je voudrais c'est l'arrêter complètement (mais pas le supprimer !). En effet quand je joue je n'ai pas besoin du shell et tout ce qui s'ensuit.

Le seul problème, comme je l'ai dit plus haut, c'est que Explorer.exe se relance automatiquement et c'est cette option là que je voudrais enlever.
Edité le 27/02/2008 à 18:49

up !

personne ne sait ???

J'ai autrefois suvi le conseille de bon nombre de sites pour régler certaines choses sous le registre, et il s'est avéré qu'une astuce censée rendre plus stable explorer, le privait de son redémarrage automatique en cas de plantage du fichier explorer.exe

En tout cas, c'est ce qu'il se produisait avec moi.



J'ai oublié l'astuce en question, du moins, l'adresse de la clé registre, mais google, devrait trouver ça.

---

Il me semble que c'est cette astuce :

Pour le rendre plus stable, il faut le désolidariser des autres processus, mais cela engendre un plus gros besoin de ram. Voici la manœuvre.

Allez à la clé : "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer"

Créez ou modifier la valeur DWORD nommée "DesktopProcess" et donnez lui la valeur "1" ("0" par défaut)

Je n'ai plus le souvenir du nom de la valeur, mais ça reste à essayer.

Par contre je lis ceci : «engendre un plus gros besoin de ram»




À essayer, et à comparer si d'autres processus prennent du poids.
Edité le 28/02/2008 à 14:09

re,
>>C'est sympa, mais non moi ce que je voudrais c'est l'arrêter complètement (mais pas le supprimer !).
Le fait de faire un 'tskill' pour moi c'est supprimer...du gestionnaire des tâches et donc de le décharger de la ram.

>>En effet quand je joue je n'ai pas besoin du shell et tout ce qui s'ensuit.
Et avant de jouer, comment ferais tu pour lancer ton jeu sans le shell????
Et pour faire ton 'tskill', comment ferais tu sans le shell????
Marabout?:@

>>J'ai autrefois suvi le conseille de bon nombre de sites pour régler certaines choses sous le registre, et il s'est avéré qu'une astuce >>censée rendre plus stable explorer, le privait de son redémarrage automatique en cas de plantage du fichier explorer.exe
salut,
Je crois qu'il y a méprises.

www.microsoft.com...
Le 'DesktopProcess' que tu abordes permet de lancer explorer.exe en 1 seul ou en 2 processus
la valeur de 0 (zéro) = 1 processus, toutes les sous-tâches d'explorer sont lancées dans 1 seul process (navigateur de fichiers, bureau, barre des tâches)
la valeur de 1 (un) = 2 processus, le navigateur est lancé dans 1 processus et le bureau, barre des tâches dans1 autre processus.

C'était juste pour permettre à l'utilisateur, [quand il y a plantage], d'avoir encore la main sur les sous-tâches d'1 processus (cas de 2 processus) et de ne pas être obligé de faire un redémarrage complet logiciel ou matériel (cas d'1 seul processus).
Mais 1 ou 2 processus, toutes les sous-tâches sont lancées et la mémoire consommée est plus importante dans le cadre de 2 processus.

houba782 a écrit:
>>J'ai autrefois suvi le conseille de bon nombre de sites pour régler certaines choses sous le registre, et il s'est avéré qu'une astuce >>censée rendre plus stable explorer, le privait de son redémarrage automatique en cas de plantage du fichier explorer.exe
salut,
Je crois qu'il y a méprises.

www.microsoft.com...
Le 'DesktopProcess' que tu abordes permet de lancer explorer.exe en 1 seul ou en 2 processus
la valeur de 0 (zéro) = 1 processus, toutes les sous-tâches d'explorer sont lancées dans 1 seul process (navigateur de fichiers, bureau, barre des tâches)
la valeur de 1 (un) = 2 processus, le navigateur est lancé dans 1 processus et le bureau, barre des tâches dans1 autre processus.

C'était juste pour permettre à l'utilisateur, [quand il y a plantage], d'avoir encore la main sur les sous-tâches d'1 processus (cas de 2 processus) et de ne pas être obligé de faire un redémarrage complet logiciel ou matériel (cas d'1 seul processus).
Mais 1 ou 2 processus, toutes les sous-tâches sont lancées et la mémoire consommée est plus importante dans le cadre de 2 processus.

Merci pour ces informations, je crois que j'aurais mieux fait de me taire, j'en ai parlé avec les mêmes connaissances que quand je l'utilisais, c'est à dire assez maigres.

Néanmoins la manip peut avoir son utilité, mais pas ici en tout cas.
 
Edité le 28/02/2008 à 14:10

Merci pour ces réponses, toutefois ce n'est pas l'objet de ma question...

Je ne voudrais pas le supprimer, ni choisir entre en lancer un ou plusieurs mais bien l' A R R E T E R sans qu'il se relance automatiquement.

Si vous voulez voir ce que je veux dire...

ouvrez le gestionnaire des taches, onglet processus et terminez explorer.exe (fichier - nouvelle tache - <explorer.exe> pour le relancer)

Et maintenant ouvrez une invite de commande (executer - <cmd>) et tapez <tskill explorer>

Là il se relance tout seul et c'est ça que je veux éviter !!!

Et pour répondre à la première réponse Explorer n'est en aucun cas indispensable au fonctionnement de Windaube, c'est de l'intox qui n'est pas faite pour déplaire à Microsoft.

Je viens de trouver sur la toile, il faut aller dans le registre à l'adresse :

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon
modifier la valeur DWORD : AutoRestartShell et mettre comme donnée : 0

Le tskill explorer arrête le processus et explorer n'est pas redémarré automatiquement.


Tu peux laisser la valeur comme tel, ou l'intégrér proprement à ton fichier batch, dans ce genre là :


«AutoRestartShell 0
tskill explorer
AutoRestartShell 1»

---

Je viens de tester et le temps est trop court pour que le changement de registre soit pris en compte, il faut donc soit laisser une pause, soit faire d'autres tskill entre.
 
Edité le 28/02/2008 à 18:47

Une autre idée serait de faire une pause pour ensuite relancer tous tes programmes, qui t'évite aussi de devoir faire CTRL + ALT + Suppr, ouvrir explorer ect...

Ici une simple touche permet de relancer tout. (quand la fenêtre est sélectionnée)

comme ceci :

:clap: :clap: :clap: :clap: :clap: :clap: :clap:

Mici beaucoup ! T'es un chef !
Edité le 28/02/2008 à 21:53

Coucou tout le monde alors voilà j'ai fini mon pti script... donc je fais partager au cas ou ça en intéresse quelques uns :D

(j'ai inséré des commentaires (exemple : rem mon_commentaire) pour que ce soit plus lisible)

---- Début du script ----

@echo off
@cls

rem On donne un titre à la fenêtre
@title Script de lancement CSS

rem Label Start qui comme son nom l'indique est le début du script "utile"
:START
rem ce paragraphe sera répété dans tout le script afin de donner une impression de bien fait :-)
@cls
@echo.
@echo Bienvenue dans ce script de lancement de CSS
@echo.
@echo.
rem fin du paragraphe

@echo ------------------------------------------------------
@echo + Arreter tous les processus inutiles ? +
@echo ------------------------------------------------------
@echo.
@echo 1.Oui
@echo 2.Non
@echo.
@echo.
@echo.
@echo.

rem on demande d'entrer une valeur, que l'on assigne à la variable A
set /p A=votre choix ?

rem on traite le choix fait par l'utilisateur
if /I "%A%"=="1" (goto :RUN)
if /I "%A%"=="2" (goto :STOP)

rem s'il se plante, on recommence en repartant au label START
goto :START

rem Label RUN ou on exécute les commandes (ici il n'y a que explorer qui est killed mais on peut en mettre d'autres)
:RUN

reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "AutoRestartShell" /t REG_DWORD /d 0 /f
@cls
tskill explorer

@cls
@echo.
@echo Bienvenue Dans ce Script de lancement de CSS
@echo.
@echo.

@echo ------------------------------------------------
@echo + Lancer Counter-Strike Source ? +
@echo ------------------------------------------------
@echo.
@echo 1.Oui
@echo 2.Non
@echo.
@echo.
@echo.
@echo.

set /p B=Votre choix ?

if /I "%B%"=="1" (goto :LOAD)
if /I "%B%"=="2" (goto :RELOAD)
rem Si l'utilisateur veut lancer CSS, on va au label LOAD qui s'en occupe (tapez 2 à cette demande si vous voulez juste tester)

goto :RUN

rem on lance CSS
:LOAD

C:\Progra~1\Steam\Steam.exe -applaunch 240

rem a la sortie du jeu, on demande pour relancer les processus killed auparavant
:RELOAD

@cls
@echo.
@echo Bienvenue Dans ce Script de lancement de CSS
@echo.
@echo.

@echo ----------------------------------------
@echo + Relancer les processus ? +
@echo ----------------------------------------
@echo.
@echo 1.Oui
@echo 2.Non
@echo.
@echo.
@echo.
@echo.

set /p C= Votre choix ?

if /I "%C%"=="1" (goto :RELAUNCH)
if /I "%C%"=="2" (goto :RUN)
goto :RELOAD

rem on relance les processus
:RELAUNCH

reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "AutoRestartShell" /t REG_DWORD /d 1 /f
start explorer
@cls

rem message de fin du script
:STOP

@cls
@echo.
@echo.
@ECHO Merci et au revoir !
@echo.
@echo Hitsch Hubert
@echo.


rem petite boucle de temporisation pour laisser le message de fin un certain temps
set /a D=0
:BOUCLE_FIN
set /a D+=1
if %D%==2000 (goto :QUIT)
goto :BOUCLE_FIN


:QUIT
exit

---- Fin du script ----

Donc si vous voulez tester faites un copie/coller de ce script dans notepad
(vous pouvez laissez les lignes de commentaires, ça ne gène pas)

Ensuite "Fichier" > "Enregistrer Sous..."

Choisissez l'emplacement et mettez comme nom de fichier nomdufichier.bat

Lancer le fichier.

ATTENTION... si vous n'avez pas counter-strike source sur votre pc, choisissez NON quand on vous demandera de le lancer.

Encore Merci YCL1 !
Edité le 29/02/2008 à 00:51

C'est sympa d'en faire profiter.

Par contre je ne comprends pas que tu fasses @echo à chaque fois, le @echo off sert justement à éviter de le réécrire le @ à chaque lignes.

Ceci marche très bien :

@echo off
:START
cls
title Script de lancement CSS
echo message
echo.
echo message

Et rien ne t'empêche de faire un @echo on en cours de script.


Ah, je ne connaissais pas la boucle de temporisation, voilà un truc qui va me servir pour remplacer certaines de mes pauses.


Moi j'utilise le batch pour le nettoyage au démarrage de session.

J'ai du mal à trouver un moyen de faire : tout supprimer dans ce dossier sauf 2

Je me contente donc de faire : supprimer 1, supprimer 3

Si tu as une idée là-dessus, je suis preneur.
 
Edité le 29/02/2008 à 03:59

C:\Progra~1\Steam\Steam.exe -applaunch 240

Pour être plus standard, avec l'adresse de Steam.

Tu peux utiliser la variable pour le chemin de Program Files, celle-ci est : %ProgramFiles%

Ta ligne peut donc s'écrire de cette façon :
%ProgramFiles%\Steam\Steam.exe -applaunch 240

Les variables disponibles que j'ai sont :

%AllUsersProfile% > C:\Documents and Settings\All Users
%AppData% > C:\Documents and Settings\<Utilisateur connecté>\Application Data
%CommonProgramFiles% > C:\Program Files\Fichiers communs
%ComputerName% > <Nom du PC>
%ProgramFiles% > C:\Program Files
%SystemDrive% > C:\
%SystemRoot% > C:\WINDOWS
%UserName% > <Utilisateur connecté>
%UserProfile% > C:\Documents and Settings\<Utilisateur connecté>
%WinDir% > C:\WINDOWS


%TEMP% > C:\Documents and Settings\<Utilisateur connecté>\Local Settings\Temp
%TMP% > C:\Documents and Settings\<Utilisateur connecté>\Local Settings\Temp
%HomeDrive% > C:\

Le C:\ est en fait le disque qui contient le système, et il varie en fonction de l'adresse que tu as fourni, %SystemRoot% peut très bien être D:\WD\ quand tu as choisi ceci au moment de l'installation.

C'est très pratique pour rendre un script compatible sur plusieurs machines, tu peux ainsi faire un script d'installation sans sortir les grands moyens avec installateur en C+ ou autre...

Exemple tu peux faire un truc personnel pour chaque session alors que le batch, lui, est le même :

@echo off
echo Bonjour %UserName% !

ou encore :

@echo off
title Installation sur la session %UserName%

Mais bon... tout n'est pas utile, mais ça reste des exemples pour te montrer le principe.